中文字幕免费精品_亚洲视频自拍_亚洲综合国产激情另类一区_色综合咪咪久久

寫(xiě)過(guò)PHP的都知道，其有個(gè)extract()非常方便，可以便捷的將字典轉(zhuǎn)換為變量，當(dāng)然到ASP中則要受限很多，特別是VBScript腳本，本文敘述的就是一種轉(zhuǎn)換的思路，可以實(shí)現(xiàn)類(lèi)似的功能。

下面我就直接提供ASP版本的extract代碼吧：

代碼如下:

'

' ASP/VBScript Dictionary extract

' Author: WangYe

' For more information please visit

'    

' This code is distributed under the BSD license

'

' collection 集合或者字典，可以通過(guò)For Each訪問(wèn)的

'            Request.Form 或者 Request.QueryString

' specified  指定必須存在的屬性，假如該屬性不存在，將自動(dòng)創(chuàng)建一個(gè)

' prefix     每個(gè)屬性的前綴修飾

' callback   對(duì)于集合或者字典的每個(gè)元素(key-value)的值進(jìn)行函數(shù)調(diào)用

'            函數(shù)原型：

'            Function filter(key, value)

'                filter = value

'            End If

'            最終值將以該函數(shù)返回的值為準(zhǔn)

'

Function extract(collection, ByVal specified, prefix, callback)

    Dim VarName, VarValue, DynObj, searchKey

    specified = "," & Replace(specified, " ", "") & ","

    Set DynObj = New DynamicObject

    For Each key In collection

        searchKey = "," & key & ","

        If InStr(1, specified, searchKey, 1)>0 Then

            specified = Replace(specified, searchKey, "")

            If Left(specified, 1) <> "," Then

                specified = "," & specified

            End If

            If Right(specified, 1) <> "," Then

                specified = specified & ","

            End If

        End If

        VarName = prefix & key

        VarValue = collection(key)

        If callback<>"" Then

            VarValue = GetRef(callback)(key, VarValue)

        End If

        DynObj.add VarName, VarValue, PROPERTY_ACCESS_READONLY

 Next

    specified_array = Split(specified, ",")

    Dim i

    For i = LBound(specified_array) To UBound(specified_array)

        If specified_array(i)<>"" Then

            DynObj.add prefix & specified_array(i), "", _

  PROPERTY_ACCESS_READONLY

        End If

    Next

    Set extract = DynObj.GetObject()

End Function

再介紹下使用方法：

代碼如下:

Dim query

Set query = extract(Request.QueryString, "name,id", "", "")

    Response.Write query.name

    Response.Write query.id

Set query = Nothing

訪問(wèn)包含上述代碼的ASP頁(yè)面，在QueryString（就是URL問(wèn)號(hào)后面的）包含name=wangye你將看到頁(yè)面輸出”wangye”，包含id=12的時(shí)候，將輸出”12″，當(dāng)然你也可以同時(shí)指定兩項(xiàng)。

你可能發(fā)現(xiàn)當(dāng)你Response.Write輸出name和id之外key的時(shí)候，程序報(bào)錯(cuò)了，因?yàn)橹付ǖ膶傩圆淮嬖冢?dāng)你在查詢(xún)字符串包含這個(gè)key的時(shí)候，程序又正常了，因?yàn)橛辛诉@個(gè)key就自動(dòng)建立了屬性，所以又可以直接Response.Write了，如何避免呢？

1. 通過(guò)extract()函數(shù)的specified參數(shù)，該參數(shù)是個(gè)以逗號(hào)隔開(kāi)key的字符串，你可以看到剛才示例代碼中運(yùn)用了這個(gè)特性，如果查詢(xún)字符串未包含相應(yīng)的key，但是你又使用了這個(gè)key，只要specified列表中有，就會(huì)自動(dòng)建立值為空的屬性，所以就不會(huì)報(bào)錯(cuò)啦。

2. 通過(guò)返回對(duì)象的hasattr_方法進(jìn)行使用前判斷，這個(gè)方法可以判斷extract()函數(shù)返回的對(duì)象是否存在相應(yīng)的屬性，比如代碼有：

代碼如下:

Dim query

Set query = extract(Request.QueryString, "name,id", "", "")

If query.hasattr_("job") Then

    Response.Write "Job : " & query.job

End If

Set query = Nothing

這里job并不在我們的specified列表中，但是不帶查詢(xún)字串的直接訪問(wèn)程序沒(méi)有報(bào)錯(cuò)，因?yàn)槲覀兺ㄟ^(guò)hasattr_在使用前進(jìn)行判斷是否存在此屬性。

3. 通過(guò)返回對(duì)象的getattr_方法進(jìn)行安全訪問(wèn)，這個(gè)方法會(huì)在使用前判斷指定的屬性是否存在，如果不存在則用默認(rèn)值替代，詳細(xì)參考DynamicObject說(shuō)明，比如代碼：

代碼如下：

Dim query

Set query = extract(Request.QueryString, "name,id", "", "")

    Response.Write "Job : " & query.getattr_("job", "No Job")

Set query = Nothing

最后再介紹下filter的使用，extract()函數(shù)的filter參數(shù)，指定的是另外一個(gè)函數(shù)名字符串，然后extract()將對(duì)每個(gè)值調(diào)用該函數(shù)進(jìn)行處理，比如過(guò)去有這樣的代碼：

代碼如下：

Dim name, job, id

name = Trim(Request.QueryString("name"))

job = Trim(Request.QueryString("job"))

id = CLng(Trim(Request.QueryString("id")))

可以看到，我們每一次都調(diào)用了Trim()函數(shù)，重復(fù)的寫(xiě)多次很麻煩，而且以后如果要改變相應(yīng)功能還要一個(gè)一個(gè)替換，通過(guò)filter參數(shù)我們可以這樣寫(xiě)：

'

' Function filter(key, value)

'   filter = Trim(value)

' End Function

'

Function filter(key, value)

    On Error Resume Next

    Select Case key

        Case "id" ' 判斷ID是否是數(shù)字

            If Not IsNumeric(value) Then

                Exit Function

            End If

            If CLng(value)<1 Then

                Exit Function

            End If

    End Select

    ' 最后記得讓函數(shù)返回值，該值在extract將被置為該返回值

    filter = Trim(value)

    If Err.Number<>0 Then

        filter = ""

    End If

End Function

Dim query

Set query = extract(Request.QueryString, "name,id,job", "", "filter")

    Response.Write query.name

    Response.Write query.job

    Response.Write query.id

Set query = Nothing

剛才我們是以Request.QueryString為例子的，當(dāng)然你也可以使用Request.Form來(lái)實(shí)現(xiàn)表單處理的更多功能，希望這篇文章能夠給你編寫(xiě)ASP帶來(lái)方便:-)

更多信息請(qǐng)查看IT技術(shù)專(zhuān)欄